Batch Converter RAR ke ZIP dengan WinRAR

17 Feb, 2024

Script batch berikut adalah sebuah alat sederhana untuk mengonversi file RAR menjadi file ZIP menggunakan perangkat lunak WinRAR. Ini dapat membantu memudahkan proses konversi antara format file yang umum digunakan. 

Batch Converter RAR ke ZIP dengan WinRAR dan Command Prompt CMD Windows

Batch Converter RAR ke ZIP dengan WinRAR

Pastikan Kamu memiliki instalasi WinRAR yang valid di direktori yang ditentukan di dalam skrip batch. Jika tidak, Kamu perlu mengganti alamat direktori dengan lokasi instalasi WinRAR yang sesuai. 

Code Batch Converter RAR to ZIP

Berikut ini adalah script Batch yg dapat kamu copy kemudian save dengan notepad ke extensi nama_converter.bat.

@echo off
:menu
CLS
echo -------------------------------------
echo.
echo RAR to ZIP Converter with WinRAR
echo created by manaluzufrin
echo.
echo Pilih Fungsi
echo 1. Batch Convert RAR to ZIP
echo 2. Batch Convert ZIP to RAR
echo 0. Keluar
echo -------------------------------------

set /p choice=Masukkan nomor fungsi (0/1/2): 

set WinRAR="C:\Program Files\WinRAR\WinRAR.exe"

if not exist %WinRAR% (
	echo WINRAR tidak ditemukan, harap instal terlebih dahulu
	pause
	exit /b
)

if "%choice%"=="0" (
	exit /b
)else if "%choice%"=="1" (
	if exist *.rar (
		echo File RAR ditemukan.
		rem Loop melalui semua file di direktori
		for %%F in (*.rar) do (
			echo File dalam proses: %%F
			MD "%%~dpnF"
			REM Ekstraksi file RAR
			%WinRAR% x "%%~nF.rar" "%%~dpnF"
			REM Buat File Zip
			%WinRAR% a -afzip "%%~nF.zip" "%%~nF"
			rmdir /s /q "%%~nF"
		)
		REM Tampilkan pesan selesai
		echo Konversi RAR to ZIP Selesai.
		pause
		goto menu
	) else (
		echo File RAR tidak ditemukan.
		pause
		goto menu
	)
)else if "%choice%"=="2" (
	if exist *.zip (
		echo File ZIP ditemukan.
		rem Loop melalui semua file di direktori
		for %%F in (*.zip) do (
			echo File dalam proses: %%F
			MD "%%~dpnF"
			REM Ekstraksi file zip
			%WinRAR% x -y "%%~nF.zip" "%%~dpnF"
			REM Buat File RAR
			%WinRAR% a -afrar -y "%%~nF.rar" "%%~nF"
			rmdir /s /q "%%~nF"
		)
		REM Tampilkan pesan selesai
		echo Konversi ZIP to RAR Selesai.
		pause
		goto menu
	) else (
		echo File ZIP tidak ditemukan.
		pause
		goto menu
	)
)else (
    echo Pilihan tidak valid.
	pause
    goto menu
)
pause

Cara Menggunakan dan Penjelasan

Copy kan script Batch Converter RAR ke ZIP ini ke folder tempat kamu ingin mengkonversikan file ZIP ke RAR atau sebaliknya. 

Ketika Kamu menjalankan script ini, Kamu akan diberikan pilihan untuk memilih fungsi yang ingin dilakukan:

  • Pilih 1 untuk mengonversi file RAR menjadi ZIP.
  • Pilih 2 untuk mengonversi file ZIP menjadi RAR.
  • Pilih 0 untuk keluar dari program.

Pastikan Kamu telah menginstal WinRAR di komputer Kamu sebelum menggunakan script ini. Jika belum, Kamu akan diberi pesan untuk menginstalnya terlebih dahulu.

Jika Kamu memilih opsi 1 dan terdapat file RAR di direktori, script akan secara otomatis mengekstrak file RAR, membuat file ZIP, dan menghapus file sementara yang telah diekstrak.

Jika Kamu memilih opsi 2 dan terdapat file ZIP di direktori, script akan mengekstrak file ZIP, membuat file RAR, dan menghapus file sementara yang telah diekstrak.

Setelah proses konversi selesai, Kamu akan diberikan pesan bahwa proses konversi telah selesai dan Kamu dapat kembali memilih fungsi atau keluar dari program.

Dengan menggunakan script batch ini, Kamu dapat dengan mudah mengonversi file RAR ke ZIP atau sebaliknya tanpa harus repot-repot melakukannya secara manual satu satu. Selamat mencoba!

Previous Post