Menggunakan Script Batch untuk Mengelola Service

30 Nov, 2023

Script batch adalah kumpulan perintah yang dijalankan secara berurutan di lingkungan sistem operasi Windows. 

Script Batch untuk Mengelola Service

Dalam konteks ini, manaluzufrin akan menjelaskan dan membahas script batch yang dirancang untuk mengelola Service MySQL80 sebagai contoh. Script ini memungkinkan pengguna untuk menghentikan atau memulai kembali Service MySQL80 dengan mudah.

Menggunakan Script Batch untuk Mengelola Service


Aplikasi Sederhana Script Batch Untuk Mengelola Service

Kamu dapat menyimpan aplikasi sederhana ini dalam ekstensi .bat dan menjalankannya dengan run as administrator dikarenakan script ini berhubungan dengan service dari Windows itu sendiri.


@echo off
:: Periksa apakah skrip dijalankan sebagai administrator
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

:: Jika bukan administrator, jalankan skrip sebagai administrator
if %errorlevel% neq 0 (
    echo Mohon jalankan skrip ini sebagai Administrator.
    echo Silakan klik kanan pada file bat dan pilih "Run as Administrator".
    pause
    goto :eof
)

:menu
CLS
ECHO.
ECHO =====================================
ECHO Pilih operasi yang ingin dilakukan:
ECHO 1. Menghentikan Service MYSQL80
ECHO 2. Memulai Service MYSQL80
ECHO 3. Status Service MYSQL80
ECHO 4. Keluar
ECHO =====================================
ECHO.

:: Tampilkan status service saat ini
echo Status Service MYSQL80:
sc query MYSQL80 | find "STATE"

set /p choice=Masukkan nomor pilihan (1/2/3/4): 

:: Lanjutkan dengan operasi sesuai pilihan pengguna
if "%choice%"=="1" (
    echo Menghentikan Service MYSQL80...
    net stop MYSQL80
    echo Service berhasil dihentikan.
    goto menu
) else if "%choice%"=="2" (
    echo Memulai Service MYSQL80...
    net start MYSQL80
    echo Service berhasil dimulai.
    goto menu
) else if "%choice%"=="3" (
    echo Status Service MYSQL80:
    sc query MYSQL80 | find "STATE"
    goto menu
) else if "%choice%"=="4" (
    echo Keluar.
    goto :eof
) else (
    echo Pilihan tidak valid. Silakan masukkan 1, 2, 3, atau 4.
    goto menu
)

Tampilan menu

  • @echo off: Menonaktifkan pencetakan baris perintah, sehingga hanya output dari perintah yang dijalankan yang akan ditampilkan.
  • :menu: Label untuk membuat loop menu sehingga pengguna dapat memilih operasi berulang kali.
  • CLS: Membersihkan layar konsol untuk memberikan tampilan yang bersih.
  • ECHO: Menampilkan teks di layar konsol untuk memberikan petunjuk kepada pengguna.
  • set /p choice=Masukkan nomor pilihan (1/2/3):: Meminta input dari pengguna untuk memilih operasi.

Mengecek Hak Akses Administrator

Periksa apakah skrip dijalankan sebagai administrator: Menggunakan perintah cacls untuk memeriksa hak akses administrator.

Jika bukan administrator: Memberikan pesan kepada pengguna untuk menjalankan skrip sebagai administrator dan menghentikan eksekusi.

Eksekusi Operasi Sesuai Pilihan Pengguna

  • if-else statement: Mengevaluasi pilihan pengguna dan melanjutkan dengan operasi yang sesuai.
  • net stop/start MYSQL80: Menghentikan atau memulai kembali Service MySQL80.
  • goto menu: Kembali ke menu utama setelah menyelesaikan operasi.

Next Post Previous Post